EEPW论坛

问 （注：我用的是44B0X的公板，板子从本论坛一站友处购得，他出售前未经过全部测试，AXD调试均在板子上进行）

--------------------文章正文--------------

   在另一个帖子《请教：44B0X在跑uc/os时，硬件连续两次重新启动的问题 》中，我描述了移植UC/OS的过程遇到的致命问题，主要现象时：系统莫名其妙重新启动两次后（从0X0启动）随即永远都运行空闲任务。
  
   但是今天在一次AXD全速调试中，发现系统运行完全正常。之后却故障依旧。

描述如下：

   下午在一次AXD调试中，我发现44BINIT.s在初始化堆栈（BL InitStacks）之后，CPSR保持为SVC模式不变，于是一路全速执行，发现测试任务和系统的空闲任务能正常切换（看LED输出结果），和前面一个帖子预期的一样。这就意味着，OS能正常使用了。这就证明我的软件部分是正确的。

   于是烧录到flash里去，却崩溃了，情况和先前描述的一样。

   再进入axd环境，全速运行，仍然崩溃。单步观察44BINIT.s中的InitStacks的代码，发现在最后初始化SVC堆栈完成之后，CPSR仍然莫名其妙改变成了IRQ模式（***请见下图***），这样，一直执行到MAIN，仍然是IRQ模式，当发生真正的时钟中断时，系统调度，然后弹出PC时，系统就崩溃了。

疑惑一：
   为什么44Binit.s初始化堆栈会出现CPSR异常改变的现象呢？？？？？
疑惑二：
   而且这时伴有一个问题，若全速运行BL InitStacks，程序便跑飞，只有单步才能走完InitStacks全过程，是否跟CPSR异常改变有关？
疑惑三：
  CPSR发生变化需要具备什么条件？
  在进入0X0之后，44binit.s首先是关WDT，然后是禁止所有中断，之后再调用Initstacks，如下：
;****************************************************
;*    START                                            *
;****************************************************
ResetHandler
    ldr        r0,=WTCON        ;watch dog disable
    ldr        r1,=0x0         
    str        r1,[r0]

    ldr        r0,=INTMSK
    ldr        r1,=0x07ffffff  ;all interrupt disable
    str        r1,[r0]
...



  以上的问题，请高人指点，小弟万分感谢，同时再次谢过帮助过我和关注过我的站友。

下一贴贴上44BINIT.s，请一并关注，谢谢。


--截图----------

   请看下图：注意椭圆框起来的内容，尤其是CPSR。

图1 CPSR在堆栈初始化时异常改变现象的截图
http://file.21ic.com.cn/upload/img/200511/200512217231635492.jpg





答 1: 贴上44BINT.s，不知道可有改善的地方？代码也读了几遍，但小弟实在太菜，不能发现玄机所在，还望有心人指点迷津。

; *******************************************************
; * NAME    : 44BINIT.S                                    *
; * Version : 10.April.2000                                *
; * Description:                                        *
; *    C start up codes                                    *
; *    Configure memory, Initialize ISR ,stacks            *
; *    Initialize C-variables                                *
; *    Fill zeros into zero-initialized C-variables        *
; *******************************************************

    GET ..\inc\option.s
    GET ..\inc\memcfg.s

;Memory Area
;GCS6 16bit(2MB) SDRAM(0xc000000-0xc1fffff)
;INTTABLE  =0xc1fff00~0xc1fffff
;STACK       =0xc7ffa00           

;Interrupt Control
INTPND        EQU    0x01e00004
INTMOD        EQU    0x01e00008
INTMSK        EQU    0x01e0000c
I_ISPR        EQU    0x01e00020
I_CMST        EQU    0x01e0001c

;Watchdog timer
WTCON        EQU    0x01d30000

;Clock Controller
PLLCON        EQU    0x01d80000
CLKCON        EQU    0x01d80004
LOCKTIME    EQU    0x01d8000c
    
;Memory Controller
REFRESH        EQU 0x01c80024

;BDMA destination register
BDIDES0     EQU 0x1f80008
BDIDES1     EQU 0x1f80028

;Pre-defined constants
USERMODE    EQU    0x10
FIQMODE        EQU    0x11
IRQMODE        EQU    0x12
SVCMODE        EQU    0x13
ABORTMODE   EQU    0x17
UNDEFMODE   EQU    0x1b
MODEMASK    EQU    0x1f
NOINT        EQU    0xc0

PDATE  EQU 0x1d2002C   ;LEE
PCONE  EQU 0x1d20028     ;LEE


    
;check if tasm.exe is used.
    GBLL    THUMBCODE
    [ {CONFIG} = 16    
THUMBCODE SETL    {TRUE}
    CODE32
    |   
THUMBCODE SETL    {FALSE}
    ]

    [ THUMBCODE
    CODE32   ;for start-up code for Thumb mode
    ]

    MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
    sub        sp,sp,#4            ;decrement sp(to store jump address)
    stmfd   sp!,{r0}            ;PUSH the work register to stack(lr does't push because it return to original address)
    ldr        r0,=$HandleLabel    ;load the address of HandleXXX to r0
    ldr        r0,[r0]                ;load the contents(service routine start address) of HandleXXX
    str        r0,[sp,#4]            ;store the contents(ISR) of HandleXXX to stack
    ldmfd   sp!,{r0,pc}            ;POP the work register and pc(jump to ISR)
    MEND

    IMPORT    |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
    IMPORT    |Image$$RW$$Base|   ; Base of RAM to initialise
    IMPORT    |Image$$ZI$$Base|   ; Base and limit of area
    IMPORT    |Image$$ZI$$Limit|  ; to zero initialise

    IMPORT  Main    ; The main entry of mon program

    AREA    Init,CODE,READONLY

    ENTRY
    b ResetHandler  ;for debug
    b HandlerUndef  ;handlerUndef
    b HandlerSWI    ;SWI interrupt handler
    b HandlerPabort ;handlerPAbort
    b HandlerDabort ;handlerDAbort
    b .            ;handlerReserved
    b HandlerIRQ
    b HandlerFIQ
    ;***IMPORTANT NOTE***
    ;If the H/W vectored interrutp mode is enabled, The above two instructions should
    ;be changed like below, to work-around with H/W bug of S3C44B0X interrupt controller.
    ; b HandlerIRQ  ->  subs pc,lr,#4
    ; b HandlerIRQ  ->  subs pc,lr,#4

VECTOR_BRANCH
    ldr pc,=HandlerEINT0    ;mGA    H/W interrupt vector table
    ldr pc,=HandlerEINT1    ;    
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567 ;
    ldr pc,=HandlerTICK        ;mGA
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT        ;
    ldr pc,=HandlerUERR01   ;mGB
    b .
    b .
    ldr pc,=HandlerTIMER0   ;mGC
    ldr pc,=HandlerTIMER1   ;
    ldr pc,=HandlerTIMER2   ;
    ldr pc,=HandlerTIMER3   ;
    ldr pc,=HandlerTIMER4   ;
    ldr pc,=HandlerTIMER5   ;mGC
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC        ;
    ldr pc,=HandlerSIO        ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD
    b .
    b .
    ldr pc,=HandlerRTC        ;mGKA
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;mGKA
    b .
    b .
    ldr pc,=HandlerADC        ;mGKB
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;mGKB
    b .
    b .
;0xe0=EnterPWDN
    ldr pc,=EnterPWDN

    LTORG    

HandlerFIQ        HANDLER HandleFIQ
HandlerIRQ        HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI        HANDLER HandleSWI
HandlerDabort    HANDLER HandleDabort
HandlerPabort    HANDLER HandlePabort

HandlerADC        HANDLER HandleADC
HandlerRTC        HANDLER HandleRTC
HandlerUTXD1    HANDLER HandleUTXD1
HandlerUTXD0    HANDLER HandleUTXD0
HandlerSIO        HANDLER HandleSIO
HandlerIIC        HANDLER HandleIIC
HandlerURXD1    HANDLER HandleURXD1
HandlerURXD0    HANDLER HandleURXD0
HandlerTIMER5    HANDLER HandleTIMER5
HandlerTIMER4    HANDLER HandleTIMER4
HandlerTIMER3    HANDLER HandleTIMER3
HandlerTIMER2    HANDLER HandleTIMER2
HandlerTIMER1    HANDLER HandleTIMER1
HandlerTIMER0    HANDLER HandleTIMER0
HandlerUERR01    HANDLER HandleUERR01
HandlerWDT        HANDLER HandleWDT
HandlerBDMA1    HANDLER HandleBDMA1
HandlerBDMA0    HANDLER HandleBDMA0
HandlerZDMA1    HANDLER HandleZDMA1
HandlerZDMA0    HANDLER HandleZDMA0
HandlerTICK        HANDLER HandleTICK
HandlerEINT4567    HANDLER HandleEINT4567
HandlerEINT3    HANDLER HandleEINT3
HandlerEINT2    HANDLER HandleEINT2
HandlerEINT1    HANDLER HandleEINT1
HandlerEINT0    HANDLER HandleEINT0


;One of the following two routines CAN be used for non-vectored interrupt.

IsrIRQ    ;using I_ISPR register.
    sub        sp,sp,#4       ;reserved for PC
    stmfd   sp!,{r8-r9}   

    ;IMPORTANT CAUTION
    ;if I_ISPC isn't used properly, I_ISPR CAN be 0 in this routine.

    ldr        r9,=I_ISPR
    ldr        r9,[r9]

    ;cmp        r9, #0x0    ;If the IDLE mode work-around is used,r9 may be 0 sometimes.
    ;beq        %F2         ;move by lee
    
    

    mov        r8,#0x0
0
    movs    r9,r9,lsr #1
    bcs        %F1
    add        r8,r8,#4
    b        %B0

1
    ldr        r9,=HandleADC
    add        r9,r9,r8
    ldr        r9,[r9]
    str        r9,[sp,#8]
    ldmfd   sp!,{r8-r9,pc}

;2
    ;ldmfd    sp!,{r8-r9}
    ;add        sp,sp,#4
    ;subs    pc,lr,#4

;****************************************************
;*    START                                            *
;****************************************************
ResetHandler
    ldr        r0,=WTCON        ;watch dog disable
    ldr        r1,=0x0         
    str        r1,[r0]

    ldr        r0,=INTMSK
    ldr        r1,=0x07ffffff  ;all interrupt disable
    str        r1,[r0]
       
   
    ;****************************************************
    ;*    Set clock control registers                        *
    ;****************************************************
    ldr    r0,=LOCKTIME
    ldr    r1,=0xfff
    str    r1,[r0]

    [ PLLONSTART
    ldr    r0,=PLLCON                            ;temporary setting of PLL
    ldr    r1,=((M_DIV<<12)+(P_DIV<<4)+S_DIV)    ;Fin=10MHz,Fout=60MHz
    str    r1,][r0]
    ]

    ldr        r0,=CLKCON         
    ldr        r1,=0x7ff8        ;All unit block CLK enable    
    str        r1,[r0]

    ;****************************************
    ;*  change BDMACON reset value for BDMA *   
    ;****************************************
    ldr     r0,=BDIDES0       
    ldr     r1,=0x40000000   ;BDIDESn reset value should be 0x40000000     
    str     r1,[r0]

    ldr     r0,=BDIDES1      
    ldr     r1,=0x40000000   ;BDIDESn reset value should be 0x40000000     
    str     r1,[r0]

    ;****************************************************
    ;*    Set memory control registers                    *     
    ;****************************************************
    ldr        r0,=SMRDATA
    ldmia   r0,{r1-r13}
    ldr        r0,=0x01c80000  ;BWSCON Address
    stmia   r0,{r1-r13}

    ;****************************************************
    ;*    Initialize stacks                                *
    ;****************************************************
    ldr        sp, =SVCStack    ;Why?
    bl        InitStacks

    ;****************************************************
    ;*    Setup IRQ handler                                *
    ;****************************************************
    ldr        r0,=HandleIRQ        ;This routine is needed
    ldr        r1,=IsrIRQ            ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    str        r1,[r0]

    ;********************************************************
    ;*    Copy and paste RW data/zero initialized data        *
    ;********************************************************
    LDR        r0, =|Image$$RO$$Limit|    ; Get pointer to ROM data
    LDR        r1, =|Image$$RW$$Base|    ; and RAM copy
    LDR        r3, =|Image$$ZI$$Base|    
    ;Zero init base => top of initialised data
            
    CMP        r0, r1        ; Check that they are different
    BEQ        %F1
0        
    CMP        r1, r3        ; Copy init data
    LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4         
    STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
    BCC        %B0
1        
    LDR        r1, =|Image$$ZI$$Limit| ; Top of zero init segment
    MOV        r2, #0
2        
    CMP        r3, r1        ; Zero init
    STRCC   r2, [r3], #4
    BCC        %B2
    
    
    
    [ :LNOT:THUMBCODE    
    B    Main        ;Don't use main() because ......
    B    .                        
    ]

    [ THUMBCODE            ;for start-up code for Thumb mode
    orr     lr,pc,#1
    bx      lr
    CODE16
    b      Main        ;Don't use main() because ......
    b       .
    CODE32
    ]

;****************************************************
;*    The function for initializing stack                *
;****************************************************
InitStacks
    ;Don't use DRAM,such as stmfd,ldmfd......
    ;SVCstack is initialized before
    ;Under toolkit ver 2.50, 'msr cpsr,r1' CAN be used instead of 'msr cpsr_cxsf,r1'

    mrs        r0,cpsr
    bic        r0,r0,#MODEMASK
    orr        r1,r0,#UNDEFMODE|NOINT
    msr        cpsr_cxsf,r1        ;UndefMode
    ldr        sp,=UndefStack
    
    orr        r1,r0,#ABORTMODE|NOINT
    msr        cpsr_cxsf,r1             ;AbortMode
    ldr        sp,=AbortStack

    orr        r1,r0,#IRQMODE|NOINT
    msr        cpsr_cxsf,r1             ;IRQMode
    ldr        sp,=IRQStack
    
    orr        r1,r0,#FIQMODE|NOINT
    msr        cpsr_cxsf,r1             ;FIQMode
    ldr        sp,=FIQStack

    bic        r0,r0,#MODEMASK|NOINT
    orr        r1,r0,#SVCMODE
    msr        cpsr_cxsf,r1             ;SVCMode
    ldr        sp,=SVCStack
    
    

    ;USER mode is not initialized.
    mov        pc,lr ;The LR register may be not valid for the mode changes.

;****************************************************
;*    The function for entering power down mode        *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
    mov        r2,r0               ;r0=CLKCON
    ldr        r0,=REFRESH        
    ldr        r3,[r0]
    mov        r1, r3
    orr        r1, r1, #0x400000   ;self-refresh enable
    str        r1, [r0]

    nop     ;Wait until self-refresh is issued. May not be needed.
    nop     ;If the other bus master holds the bus, ...
    nop        ; mov r0, r0
    nop
    nop
    nop
    nop

;enter POWERDN mode
    ldr        r0,=CLKCON
    str        r2,[r0]

;wait until enter SL_IDLE,STOP mode and until wake-up
    ldr        r0,=0x10
0   subs    r0,r0,#1
    bne        %B0

;exit from DRAM/SDRAM self refresh mode.
    ldr        r0,=REFRESH
    str        r3,[r0]
    mov        pc,lr

    LTORG

SMRDATA DATA
    
;*****************************************************************
;* Memory configuration has to be optimized for best performance *
;* The following parameter is not optimized.                     *
;*****************************************************************

;*** memory access cycle parameter strategy ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM Parameters:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM refresh rate is for 40Mhz.

;bank0    16bit BOOT ROM 32M
;bank1    8bit  USB(PDIUSBD12)
;bank2    16bit IDE
;bank3    16bit net(RTL8019AS)
;bank4    no
;bank5    no
;bank6    16bit SDRAM 8M
;bank7    no

    [ BUSWIDTH=16
    DCD 0X11110101    ;Bank0=OM][1:0], Bank1~Bank7=16bit
    | ;BUSWIDTH=32
    DCD 0x22222220    ;Bank0=OM[1:0], Bank1~Bank7=32bit
    ]
    DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))    ;GCS0
    DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))    ;GCS1
    DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))    ;GCS2
    DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))    ;GCS3
    DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))    ;GCS4
    DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))    ;GCS5
    [ BDRAMTYPE="DRAM"
        DCD ((B6_MT<<15)+(B6_Trcd<<4)+(B6_Tcas<<3)+(B6_Tcp<<2)+(B6_CAN))    ;GCS6 check the MT value in parameter.a
        DCD ((B7_MT<<15)+(B7_Trcd<<4)+(B7_Tcas<<3)+(B7_Tcp<<2)+(B7_CAN))    ;GCS7
    | ;"SDRAM"
        DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
        DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
    ]
    DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)    ;REFRESH RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
    DCD 0x10            ;SCLK power down mode, BANKSIZE 32M/32M
    DCD 0x20            ;MRSR6 CL=2clk
    DCD 0x20            ;MRSR7

    ALIGN

    AREA RamData, DATA, READWRITE

    ^    (_ISR_STARTADDRESS-0x500)
                
UserStack    #    256    ;c1(c7)ffa00
SVCStack    #    256    ;c1(c7)ffb00
UndefStack    #    256    ;c1(c7)ffc00
AbortStack    #    256    ;c1(c7)ffd00
IRQStack    #    256    ;c1(c7)ffe00
FIQStack    #    0    ;c1(c7)fff00


        ^    _ISR_STARTADDRESS
HandleReset        #    4
HandleUndef        #    4
HandleSWI        #    4
HandlePabort    #    4
HandleDabort    #    4
HandleReserved    #    4
HandleIRQ        #    4
HandleFIQ        #    4

;Don't use the label 'IntVectorTable',
;because ARMasm.exe CANn't recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable
HandleADC        #    4
HandleRTC        #    4
HandleUTXD1        #    4
HandleUTXD0        #    4
HandleSIO        #    4
HandleIIC        #    4
HandleURXD1        #    4
HandleURXD0        #    4
HandleTIMER5    #    4
HandleTIMER4    #    4
HandleTIMER3    #    4
HandleTIMER2    #    4
HandleTIMER1    #    4
HandleTIMER0    #    4
HandleUERR01    #    4
HandleWDT        #    4
HandleBDMA1        #    4
HandleBDMA0        #    4
HandleZDMA1        #    4
HandleZDMA0        #    4
HandleTICK        #    4
HandleEINT4567    #    4
HandleEINT3        #    4
HandleEINT2        #    4
HandleEINT1        #    4
HandleEINT0        #    4   ;0xc1(c7)fff84

        END
答 2: 我愿意将项目文件发给有44BOX开发板的有经验的高手测试    
   其中包含16级灰度的320*240的LCD驱动（写到了在屏幕上任意坐标显示字符的层次），另含8019网卡的低层硬件驱动函数（收发包还没写完），有愿意帮助我测试的高手，请留下email，我发过去，并期待你的测试结果，因为有可能是开发板本身的问题。

   快1个月了，也就只有这点进展（业余时间学习的），没有别的能贡献出来了，唉，连OS都没搞定。
   答 3: 你是用简易JTAG吧?你是用简易JTAG吧?我也出现过和你一摸一样的问题,后来换成仿真器就好了 答 4: kingpoo您好！谢谢您的提醒，您说得对，我确实是用简易JTAG，能简单描述一下你的分析么？谢谢。
或者我能用信件向您讨教么？ 答 5: 我原来调试的程序没有问题,就是莫明奇妙地进入了IRQ模式!我原来调试的程序没有问题,就是莫明奇妙地进入了IRQ模式!后来我怀疑是JTAG有问题,就换了个EBEST的仿真器试了一下,居然是对的,并没有变成IRQ模式!我怀疑是调试代理的BUG 答 6: 恩你调试的是uc/os么？也是发现在初始化堆栈之后就进入了irq模式吗？


如果是调试器的问题，那么我不调试，而直接将elf文件烧到flash中，uc/os仍然在第2个时钟节拍服务弹出PC时崩溃。


还有其他的调试或者烧写代理么？ 答 7: 我是在调试ucos,具体我不是很清楚.我是在调试ucos,具体我不是很清楚.
uc/os仍然在第2个时钟节拍服务弹出PC时崩溃是因为中断服务程序要问题 答 8: 谢谢各位关注，汇报最新情况该问题今天上午获得了解决，我重新写了44binit.s中的堆栈初始化子程序，改动的地方是在每一次写入新模式到CPSR之后，立即将SPSR写入SVC模式的控制字，这样，初始化堆栈完毕之后，CPSR和SPSR均为SVC模式，未出现上文描述的奇怪情况，在AXD模式下，全速运行程序，uc/os-ii能正常跑起来了。

至于原来的初始化堆栈子程序有问题，也可能是硬件本身的问题，看来，购买未经过严格测试的便宜的开发板有较大的风险，很容易出一些问题且得不到服务。

再次谢谢各位帮助过我的站友！