EEPW论坛

STM32的启动流程大致可分为以下几步：

1、设置堆栈

2、跳转到Reset_Handler

3、Reset_Handler调用SystemInit完成时钟、中断向量偏移的初始化工作，然后跳转到__main，__main函数会完成RW、ZI数据段的重定位工作，即将ROM中的RW数据拷贝到RAM中，将ZI段清零，然后跳转到_rt_entry进行Stack和Heap的初始化。

4、跳转到真正的main函数。

ST官方给我们提供了启动文件，我们可以通过启动文件来详细地分析STM32的启动流程。我们以STM32L431为例，分析其MDK平台的启动文件：startup_stm32l431xx.s，首先来熟悉启动文件涉及的几个汇编命令。

一、 设置Stack（栈）大小

Stack_Size EQU     0x400

                AREA    STACK, NOINIT, READWRITE, ALIGN=3

Stack_Mem       SPACE   Stack_Size

__initial_sp

开辟栈的大小为 0X00000400（1KB），名字为 STACK， NOINIT 即不初始化，可读可写， 8（2^3）字节对齐。

栈的作用是用于局部变量，函数调用，函数形参等的开销，栈的大小不能超过内部SRAM 的大小。如果编写的程序比较大，定义的局部变量很多，那么就需要修改栈的大小。如果某一天，你写的程序出现了莫名奇怪的错误，并进入了HardFault 的时候，这时你就要考虑下是不是栈不够大，溢出了。

EQU：宏定义的伪指令，相当于等于，类似于 C 中的 define。

AREA：告诉汇编器汇编一个新的代码段或者数据段。 STACK 表示段名，这个可以任意命名； NOINIT 表示不初始化； READWRITE 表示可读可写， ALIGN=3，表示按照 2^3对齐，即 8 字节对齐。

SPACE：用于分配一定大小的内存空间，单位为字节。这里指定大小等于 Stack_Size。

标号__initial_sp 紧挨着 SPACE 语句放置，表示栈的结束地址，即栈顶地址，栈是由高向低生长的。

二、设置Heap（堆）大小

Heap_Size      EQU     0x200

                AREA    HEAP, NOINIT, READWRITE, ALIGN=3

__heap_base

Heap_Mem        SPACE   Heap_Size

__heap_limit

开辟堆的大小为 0X00000200（512 字节），名字为 HEAP， NOINIT 即不初始化，可读可写， 8（2^3）字节对齐。 __heap_base 表示对的起始地址， __heap_limit 表示堆的结束地址。堆是由低向高生长的，跟栈的生长方向相反。

堆主要用来动态内存的分配，malloc()函数申请的内存就在堆上面，但一般都是用开发者自己实现的malloc。

三、定义中断向量表

               PRESERVE8

                THUMB

; Vector Table Mapped to Address 0 at Reset

                AREA    RESET, DATA, READONLY

                EXPORT  __Vectors

                EXPORT  __Vectors_End

                EXPORT  __Vectors_Size

__Vectors       DCD     __initial_sp               ; Top of Stack

                DCD     Reset_Handler              ; Reset Handler

                DCD     NMI_Handler                ; NMI Handler

                DCD     HardFault_Handler          ; Hard Fault Handler

                DCD     MemManage_Handler          ; MPU Fault Handler

                ;内容过长，省略一部分...

                DCD     PendSV_Handler             ; PendSV Handler

                DCD     SysTick_Handler            ; SysTick Handler

                ; External Interrupts

                DCD     WWDG_IRQHandler                   ; Window WatchDog

                DCD     FLASH_IRQHandler                  ; FLASH

                DCD     RCC_IRQHandler                    ; RCC

                ;内容过长，省略一部分...

                DCD     FPU_IRQHandler                    ; FPU

                DCD     CRS_IRQHandler                    ; CRS interrupt

__Vectors_End

__Vectors_Size  EQU  __Vectors_End - __Vectors

对于 Cortex-M3 内核，ARM 规定向量表的起始位置存放的是栈顶指针 MSP 的地址值，紧接着存放的是复位中断入口函数的地址。当刚上电的时候，硬件会根据向量表的地址找到向量表的具体位置（对于向量表的地址是可以通过 NVIC 中的一个重定位寄存器来设置的，复位时该寄存器的值为0），然后会根据向量表中的这两个数据，设置 SP、PC 的值，这时 CPU 就会从复位中断的入口函数开始取指令运行程序。

“DCD     __initial_sp”这行代码是将__initial_sp的值放到其实位置，硬件会初步将SP设置为__initial_sp，这样才能调用后续的C代码，例如SystemInit。为什么说是初步设置呢，因为后面用户可以重新设置SP指针。

PRESERVE8： 指定当前文件的堆栈按照 8 字节对齐。

THUMB：表示后面指令兼容 THUMB 指令。 THUBM 是 ARM 以前的指令集， 16bit，现在 Cortex-M 系列的都使用 THUMB-2 指令集， THUMB-2 是 32 位的，兼容 16 位和 32 位的指令，是 THUMB 的超集。

__Vectors 为向量表起始地址， __Vectors_End 为向量表结束地址，两个相减即可算出向量表大小。

 向量表从 FLASH 的 0 地址开始放置，以 4 个字节为一个单位，地址 0 存放的是栈顶地址， 0X04 存放的是复位程序的地址，以此类推。从代码上看，向量表中存放的都是中断服务函数的函数名， C 语言中的函数名就是一个地址。

DCD：分配一个或者多个以字为单位的内存，以四字节对齐，并要求初始化这些内存。在向量表中， DCD 分配了一堆内存，并且以 ESR 的入口地址初始化它们。

四、默认中断函数

                AREA    |.text|, CODE, READONLY

; Reset handler

Reset_Handler    PROC

                 EXPORT  Reset_Handler             [WEAK]

        IMPORT  SystemInit

        IMPORT  __main

                 LDR     R0, =SystemInit

                 BLX     R0

                 LDR     R0, =__main

                 BX      R0

                 ENDP

; Dummy Exception Handlers (infinite loops which can be modified)

NMI_Handler     PROC

                EXPORT  NMI_Handler                [WEAK]

                B       .

                ENDP

HardFault_Handler\

                PROC

                EXPORT  HardFault_Handler          [WEAK]

                B       .

                ENDP

;内容过长，省略一部分...

PendSV_Handler  PROC

                EXPORT  PendSV_Handler             [WEAK]

                B       .

                ENDP

SysTick_Handler PROC

                EXPORT  SysTick_Handler            [WEAK]

                B       .

                ENDP

Default_Handler PROC

        EXPORT     WWDG_IRQHandler                   [WEAK]

        EXPORT     PVD_PVM_IRQHandler                [WEAK]

        ;内容过长，省略一部分...

        EXPORT     FPU_IRQHandler                    [WEAK]        

        EXPORT     CRS_IRQHandler                    [WEAK]

WWDG_IRQHandler

PVD_PVM_IRQHandler

;内容过长，省略一部分...

FPU_IRQHandler

CRS_IRQHandler

                B       .

                ENDP

AREA    |.text|, CODE, READONLY定义了一个只读的.text代码段。

PROC和 ENDP 相当于一个括号，表示中间是一个过程的代码。接下来就是非常重要的一个中断：复位中断Reset_Handler，它是MCU上电后的第一个函数，它先调用SystemInit完成时钟、中断向量偏移的初始化工作，然后跳转到__main，__main函数会完成RW、ZI数据段的重定位工作，即将ROM中的RW数据拷贝到RAM中，同时将ZI段清零。

启动文件帮我们默认完成了中断函数的编写，例如NMI_Handler、HardFault_Handler等，函数的功能相当于while(1)死循环，这些函数都是用WEAK弱定义的，如果需要，我们可以重写这些中断函数。

五、设置堆栈的初始化方式

  ALIGN

                 IF      :DEF:__MICROLIB

                 EXPORT  __initial_sp

                 EXPORT  __heap_base

                 EXPORT  __heap_limit

                 ELSE

                 IMPORT  __use_two_region_memory

                 EXPORT  __user_initial_stackheap

__user_initial_stackheap

                 LDR     R0, =  Heap_Mem

                 LDR     R1, =(Stack_Mem + Stack_Size)

                 LDR     R2, = (Heap_Mem +  Heap_Size)

                 LDR     R3, = Stack_Mem

                 BX      LR

                 ALIGN

                 ENDIF

                 END

前面设置的是堆栈的大小，这里还需要对堆栈做一些初始化工作，主要是将这些区域进行清零。

ALIGN：对指令或者数据存放的地址进行对齐，后面会跟一个立即数。缺省表示 4 字节对齐。

IF,ELSE,ENDIF：汇编的条件分支语句，跟 C 语言的 if ,else 类似

END：文件结束

程序有两条分支可选，首先判断是否定义了__MICROLIB ，如果定义了这个宏则有C库完成堆栈的初始化，：赋予标号__initial_sp（栈顶地址）、 __heap_base（堆起始地址）、 __heap_limit（堆结束地址）全局属性，可供外部文件调用，例如C文件只要externa int __initial_sp，就可以使用这个变量了。有关这个宏我们在 KEIL 里面配置，如下图所示。然后堆栈的初始化就由 C 库函数_main 来完成。

来源： 整理文章为传播相关技术，网络版权归原作者所有，如有侵权，请联系删除。