EEPW论坛

问 具体INIT.S程序如下：
; *******************************************************
; * 程序名  : 44BINIT.S                                    *
; * 版本    : 2000.04.10                                *
; * 描述:                                                *
; *    C 启动代码                                           *
; *    配置存储器，初始化中断服务程序，堆栈                *
; *    初始化C变量                                         *
; *    把C变量初始化为0                                       *
; *******************************************************

;存储器区域
;GCS6 64M 16bit(8MB) DRAM/SDRAM(0xc000000-0xc7fffff)
;APP    RAM=0xc000000~0xc7effff
;44BMON RAM=0xc7f0000-0xc7fffff
;STACK       =0xc7ffa00           

;中断控制
INTPND        EQU    0x01e00004
INTMOD        EQU    0x01e00008
INTMSK        EQU    0x01e0000c
I_ISPR        EQU    0x01e00020
I_CMST        EQU    0x01e0001c

;看门狗时钟
WTCON        EQU    0x01d30000

;时钟控制
PLLCON        EQU    0x01d80000
CLKCON        EQU    0x01d80004
LOCKTIME    EQU    0x01d8000c
    
;存储器控制
REFRESH        EQU 0x01c80024

;BDMA 寄存器
BDIDES0     EQU 0x1f80008
BDIDES1     EQU 0x1f80028

;预定义常量
USERMODE    EQU    0x10
FIQMODE        EQU    0x11
IRQMODE        EQU    0x12
SVCMODE        EQU    0x13
ABORTMODE   EQU    0x17
UNDEFMODE   EQU    0x1b
MODEMASK    EQU    0x1f
NOINT        EQU    0xc0

;检查是否用的tasm.exe
    GBLL    THUMBCODE
    [ {CONFIG} = 16    
THUMBCODE SETL    {TRUE}
    CODE32
    |   
THUMBCODE SETL    {FALSE}
    ]

    [ THUMBCODE
    CODE32   
    ]

    MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
    sub        sp,sp,#4        ;消耗堆栈指针(存储跳转地址)
    stmfd   sp!,{r0}        ;把工作寄存器入栈
    ldr        r0,=$HandleLabel;将HandleXXX的地址读入寄存器r0
    ldr        r0,[r0]            ;读入HandleXXX的内容(服务程序的起始地址)
    str        r0,[sp,#4]        ;存储HandleXXX的内容(中断服务程序)到堆栈
    ldmfd   sp!,{r0,pc}        ;出栈工作寄存器和pc(跳转到中断服务程序)
    MEND

    IMPORT    |Image$$RO$$Limit|  ; ROM代码的结束 (=ROM数据的开始)
    IMPORT    |Image$$RW$$Base|   ; 初始RAM的基址
    IMPORT    |Image$$ZI$$Base|   ; 域的基址和限制
    IMPORT    |Image$$ZI$$Limit|  ; 初始0

    IMPORT  Main    ;C 语言入口函数Main

    AREA    Init,CODE,READONLY

    ENTRY
    b ResetHandler  ;for debug
    b HandlerUndef  ;handlerUndef
    b HandlerSWI    ;SWI interrupt handler
    b HandlerPabort ;handlerPAbort
    b HandlerDabort ;handlerDAbort
    b .                ;handlerReserved
    b HandlerIRQ
    b HandlerFIQ
    ;***注意***
    ;若 H/W向量中断模式可用, 则上述两指令应作如下更改
    ; b HandlerIRQ  ->  subs pc,lr,#4
    ; b HandlerFIQ  ->  subs pc,lr,#4

VECTOR_BRANCH
    ldr pc,=HandlerEINT0    ;mGA    H/W 中断向量表
    ldr pc,=HandlerEINT1    ;    
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567 ;
    ldr pc,=HandlerTICK        ;mGA
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT        ;
    ldr pc,=HandlerUERR01   ;mGB
    b .
    b .
    ldr pc,=HandlerTIMER0   ;mGC
    ldr pc,=HandlerTIMER1   ;
    ldr pc,=HandlerTIMER2   ;
    ldr pc,=HandlerTIMER3   ;
    ldr pc,=HandlerTIMER4   ;
    ldr pc,=HandlerTIMER5   ;mGC
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC        ;
    ldr pc,=HandlerSIO        ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD
    b .
    b .
    ldr pc,=HandlerRTC        ;mGKA
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;mGKA
    b .
    b .
    ldr pc,=HandlerADC        ;mGKB
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;mGKB
    b .
    b .
    ;0xe0=EnterPWDN
    ldr pc,=EnterPWDN

    LTORG    

HandlerFIQ        HANDLER HandleFIQ
HandlerIRQ        HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI        HANDLER HandleSWI
HandlerDabort    HANDLER HandleDabort
HandlerPabort    HANDLER HandlePabort

HandlerADC        HANDLER HandleADC
HandlerRTC        HANDLER HandleRTC
HandlerUTXD1    HANDLER HandleUTXD1
HandlerUTXD0    HANDLER HandleUTXD0
HandlerSIO        HANDLER HandleSIO
HandlerIIC        HANDLER HandleIIC
HandlerURXD1    HANDLER HandleURXD1
HandlerURXD0    HANDLER HandleURXD0
HandlerTIMER5    HANDLER HandleTIMER5
HandlerTIMER4    HANDLER HandleTIMER4
HandlerTIMER3    HANDLER HandleTIMER3
HandlerTIMER2    HANDLER HandleTIMER2
HandlerTIMER1    HANDLER HandleTIMER1
HandlerTIMER0    HANDLER HandleTIMER0
HandlerUERR01    HANDLER HandleUERR01
HandlerWDT        HANDLER HandleWDT
HandlerBDMA1    HANDLER HandleBDMA1
HandlerBDMA0    HANDLER HandleBDMA0
HandlerZDMA1    HANDLER HandleZDMA1
HandlerZDMA0    HANDLER HandleZDMA0
HandlerTICK        HANDLER HandleTICK
HandlerEINT4567    HANDLER HandleEINT4567
HandlerEINT3    HANDLER HandleEINT3
HandlerEINT2    HANDLER HandleEINT2
HandlerEINT1    HANDLER HandleEINT1
HandlerEINT0    HANDLER HandleEINT0


IsrIRQ    ;用 I_ISPR 寄存器.
    sub        sp,sp,#4       
    stmfd   sp!,{r8-r9}  

    ;特别注意
    ;若I_ISPC 用得不恰当, 在这段程序中I_ISPR 可能是0.

    ldr        r9,=I_ISPR
    ldr        r9,[r9]

    cmp        r9, #0x0    ;若IDLE模式工作区被用,
                        ;r9有时可能为0.
    beq        %F2            ;那样，就从ISR返回.

    mov        r8,#0x0
0
    movs    r9,r9,lsr #1
    bcs        %F1
    add        r8,r8,#4
    b        %B0

1
    ldr        r9,=0xc7fff20 ;获得是哪个中断请求.
    add        r9,r9,r8
    ldr        r9,[r9]
    str        r9,[sp,#8]
    ldmfd   sp!,{r8-r9,pc}

2
    ldmfd    sp!,{r8-r9}
    add        sp,sp,#4
    subs    pc,lr,#4

;****************************************************
;*    启动                                            *
;****************************************************
ResetHandler
    ldr        r0,=WTCON        ;禁止看门狗
    ldr        r1,=0x0         
    str        r1,[r0]

    ldr        r0,=INTMSK
    ldr        r1,=0x07ffffff  ;屏蔽所有中断
    str        r1,[r0]

    ;****************************************************
    ;*    设置时钟控制寄存器                                *
    ;****************************************************
    ldr        r0,=LOCKTIME
    ldr        r1,=0xfff
    str        r1,[r0]

    ldr        r0,=CLKCON         
    ldr        r1,=0x7ff8        ;所有单元块时钟可用
    str        r1,[r0]

    ;****************************************
    ;*  改变 BDMACON 复位值 for BDMA        *   
    ;****************************************
    ldr     r0,=BDIDES0       
    ldr     r1,=0x40000000   ;BDIDESn 复位值应该是 0x40000000     
    str     r1,[r0]

    ldr     r0,=BDIDES1      
    ldr     r1,=0x40000000   ;BDIDESn 复位值应该是 0x40000000     
    str     r1,[r0]

    ;****************************************************
    ;*    设置存储器控制寄存器                            *     
    ;****************************************************
    ldr        r0,=SMRDATA
    ldmia   r0,{r1-r13}
    ldr        r0,=0x01c80000  ;BWSCON 地址
    stmia   r0,{r1-r13}

    ;****************************************************
    ;*    初始堆栈                                        *
    ;****************************************************
    ldr        sp, =SVCStack    
    bl        InitStacks

    ;****************************************************
    ;*    设置 IRQ 处理                                    *
    ;****************************************************
    ldr        r0,=HandleIRQ        
    ldr        r1,=IsrIRQ            
    str        r1,[r0]

    ;********************************************************
    ;*    将数据段拷贝到RAM中，将零初始化数据段清零        *
    ;********************************************************
    LDR        r0, =|Image$$RO$$Limit|    ; 得到 ROM 数据和 RAM 拷贝的指针
    LDR        r1, =|Image$$RW$$Base|    
    LDR        r3, =|Image$$ZI$$Base|    
    ;Zero init base => top of initialised data
            
    CMP        r0, r1            ; 比较异同
    BEQ        %F1
0        
    CMP        r1, r3            ; 拷贝初始数据
    LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4         
    STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
    BCC        %B0
1        
    LDR        r1, =|Image$$ZI$$Limit| ; 初始化0段的首位置
    MOV        r2, #0
2        
    CMP        r3, r1            ; 初始化0
    STRCC   r2, [r3], #4
    BCC        %B2

    [ :LNOT:THUMBCODE
    BL    Main                
    B    .                        
    ]

    [ THUMBCODE            ;Thumb模式的启动代码
    orr     lr,pc,#1
    bx      lr
    CODE16
    bl      Main        
    b       .
    CODE32
    ]

;****************************************************
;*    初始化各模式下的栈指针                             *
;****************************************************
InitStacks
    ;不用 DRAM,例如stmfd,ldmfd......
    ;SVCstack在之前初始化
    
    mrs        r0,cpsr
    bic        r0,r0,#MODEMASK
    orr        r1,r0,#UNDEFMODE|NOINT
    msr        cpsr_cxsf,r1            ;未定义指令中止模式
    ldr        sp,=UndefStack
    
    orr        r1,r0,#ABORTMODE|NOINT
    msr        cpsr_cxsf,r1             ;数据访问终止模式
    ldr        sp,=AbortStack

    orr        r1,r0,#IRQMODE|NOINT
    msr        cpsr_cxsf,r1             ;外部中断模式
    ldr        sp,=IRQStack
    
    orr        r1,r0,#FIQMODE|NOINT
    msr        cpsr_cxsf,r1             ;快速中断模式
    ldr        sp,=FIQStack

    bic        r0,r0,#MODEMASK|NOINT
    orr        r1,r0,#SVCMODE
    msr        cpsr_cxsf,r1             ;管理模式
    ldr        sp,=SVCStack

    ;用户模式不用被初始化.
    mov        pc,lr ;由于模式的变化，LR寄存器可能不正确.

;****************************************************
;*    进入 power down 模式                            *
;****************************************************
;void EnterPWDN(int CLKCON);
EnterPWDN
    mov        r2,r0               ;r0=CLKCON
    ldr        r0,=REFRESH        
    ldr        r3,[r0]
    mov        r1, r3
    orr        r1, r1, #0x400000   ;自动刷新可用
    str        r1, [r0]

    nop     ;等待直到自动刷新产生影响.
    nop     
    nop        
    nop
    nop
    nop
    nop

;进入power down模式
    ldr        r0,=CLKCON
    str        r2,[r0]

;等待直到进入 SL_IDLE,STOP mode 和到 wake-up
    ldr        r0,=0x10
0   subs    r0,r0,#1
    bne        %B0

;从 DRAM/SDRAM 自动刷新模式退出.
    ldr        r0,=REFRESH
    str        r3,[r0]
    mov        pc,lr

    LTORG

SMRDATA DATA
;*****************************************************************
;* 存储器配置必须要做到优化，以实现更好的性能                    *
;* 下面的参数并不是最优化的.                                     *
;*****************************************************************

;*** 存储器访问参数策略 ***
; 1) Even FP-DRAM, EDO setting has more late fetch point by half-clock
; 2) The memory settings,here, are made the safe parameters even at 66Mhz.
; 3) FP-DRAM 参数:tRCD=3 for tRAC, tcas=2 for pad delay, tcp=2 for bus load.
; 4) DRAM 刷新率为40Mhz.

    ;DCD 0x11110090    ;Bank0=OM[1:0], Bank1~Bank7=16bit, bank2=8bit
    DCD 0x11110000    ;Bank0=OM[1:0], Bank1~Bank2=8Bit,Bank3~Bank7=16bit
    DCD 0x600    ;GCS0
    DCD 0X54a0    ;GCS1 ;//0X7bc0    ;GCS1
    DCD 0X7ffc    ;GCS2 ;//0X7fc0    ;GCS2
    DCD 0X7ffc    ;GCS3
    DCD 0X7ffc    ;GCS4
    DCD 0X7ffc    ;GCS5
    DCD 0X18000 ;GCS6
    DCD 0X18000 ;GCS7
    DCD 0x820591    ;更新 RFEN=1, TREFMD=0, trp=3clk, trc=5clk, tchr=3clk,count=1019
    DCD 0x16            ;SCLK power down mode, BANKSIZE 32M/32M
    DCD 0x20            ;MRSR6 CL=2clk
    DCD 0x20            ;MRSR7

    ALIGN


    AREA StackData, DATA, READWRITE

            %    256    
UserStack    
            %    256    ;c1(c7)ffa00
SVCStack    
            %    256    ;c1(c7)ffb00
UndefStack    
            %    256    ;c1(c7)ffc00
AbortStack    
            %    256    ;c1(c7)ffd00
IRQStack    
            %    256    ;c1(c7)ffe00
FIQStack    
            %    0    ;c1(c7)fff00


HandleReset    %    4
HandleUndef    %    4
HandleSWI    %    4
HandlePabort    %    4
HandleDabort    %    4
HandleReserved    %    4
HandleIRQ    %    4
HandleFIQ    %    4

    EXPORT HandleUndef
    EXPORT HandleSWI
    EXPORT HandlePabort
    EXPORT HandleDabort
    
;勿用标识符 ''IntVectorTable'',
;因为ARMasm.exe 不能正确地识别该标识.
;中断向量表
HandleADC        %    4
HandleRTC        %    4
HandleUTXD1        %    4
HandleUTXD0        %    4
HandleSIO        %    4
HandleIIC        %    4
HandleURXD1        %    4
HandleURXD0        %    4
HandleTIMER5    %    4
HandleTIMER4    %    4
HandleTIMER3    %    4
HandleTIMER2    %    4
HandleTIMER1    %    4
HandleTIMER0    %    4
HandleUERR01    %    4
HandleWDT        %    4
HandleBDMA1        %    4
HandleBDMA0        %    4
HandleZDMA1        %    4
HandleZDMA0        %    4
HandleTICK        %    4
HandleEINT4567    %    4
HandleEINT3        %    4
HandleEINT2        %    4
HandleEINT1        %    4
HandleEINT0        %    4   ;0xc1(c7)fff84

        END
帮忙看一下INIT.S有没有问题？
C代码都是参照示例来的没有问题，烧在FLASH上运行，也是这个现象。 答 1: 要定义好数据段的地址!AREA RamData, DATA, READWRITE

    ^    (_ISR_STARTADDRESS-0x500)
                
UserStack    #    256    ;c1(c7)ffa00
SVCStack    #    256    ;c1(c7)ffb00
UndefStack    #    256    ;c1(c7)ffc00
AbortStack    #    256    ;c1(c7)ffd00
IRQStack    #    256    ;c1(c7)ffe00
FIQStack    #    0    ;c1(c7)fff00


        ^    _ISR_STARTADDRESS
HandleReset        #    4
HandleUndef        #    4
HandleSWI        #    4
HandlePabort    #    4
HandleDabort    #    4
HandleReserved    #    4
HandleIRQ        #    4
HandleFIQ        #    4

;Do not use the label 'IntVectorTable',
;because ARMasm.exe CAN not recognize this label correctly.
;the value is different with an address you think it may be.
;IntVectorTable

HandleADC        #    4    ;HandlerADC
HandleRTC        #    4
HandleUTXD1        #    4
HandleUTXD0        #    4
HandleSIO        #    4
HandleIIC        #    4
HandleURXD1        #    4
HandleURXD0        #    4
HandleTIMER5    #    4
HandleTIMER4    #    4
HandleTIMER3    #    4
HandleTIMER2    #    4
HandleTIMER1    #    4
HandleTIMER0    #    4
HandleUERR01    #    4
HandleWDT        #    4
HandleBDMA1        #    4
HandleBDMA0        #    4
HandleZDMA1        #    4
HandleZDMA0        #    4
HandleTICK        #    4
HandleEINT4567    #    4
HandleEINT3        #    4
HandleEINT2        #    4
HandleEINT1        #    4
HandleEINT0        #    4   ;0xc7fff84

        END 答 2: _RAM_STARTADDRESS  EQU   0xc000000_RAM_STARTADDRESS  EQU   0xc000000
_ISR_STARTADDRESS   EQU   0xc7fff00 ;GCS6:64M SDRAM
答 3: 谢谢为什么ADS编译时总是不认
^    (_ISR_STARTADDRESS-0x500)
总是编译出错。 答 4: 我调试中断也跑飞啊
sunny05

你的外部中断调试好了吗？
我的也跑飞
（自己做的板子） 答 5: 要注意语法: ^    _ISR_STARTADDRESS_RAM_STARTADDRESS  EQU   0xc000000
_ISR_STARTADDRESS   EQU   0xc7fff00 ;GCS6:64M SDRAM
答 6: 外部中断不能用JTAG调试,你是否用的是JTAG调试的 答 7: 中断向量要在FALSH中烧写了中断向量才能正确的进入中断 答 8: 外部中断不能用JTAG调试,你是否用的是JTAG调试的？？？？不是吧，怎么会不能呢，只不过会丢掉吧，