问 数的大小超过255，汇编怎么写，谢谢。 答 1: 周的库;------------------------------------------------------------------------
;|              双字节十六进制整数转换成双字节ＢＣＤ码整数              |
;|                                                                      |
;|              入口：  待转换的双字节十六进制整数在R6、R7中。          |
;|              影响：  PSW、A、R2～R7                                  |
;|              调用：  无                                              |
;|              出口：  转换后的三字节ＢＣＤ码整数在R3、R4、R5中。      |
;------------------------------------------------------------------------
HB2:            CLR     A       ;ＢＣＤ码初始化
                MOV     R3,A
                MOV     R4,A
                MOV     R5,A
                MOV     R2,#10H ;转换双字节十六进制整数
HB20:           MOV     A,R7    ;从高端移出待转换数的一位到CY中
                RLC     A
                MOV     R7,A
                MOV     A,R6
                RLC     A
                MOV     R6,A
                MOV     A,R5    ;ＢＣＤ码带进位自身相加，相当于乘２
                ADDC    A,R5
                DA      A       ;十进制调整
                MOV     R5,A
                MOV     A,R4
                ADDC    A,R4
                DA      A
                MOV     R4,A
                MOV     A,R3
                ADDC    A,R3
                MOV     R3,A    ;双字节十六进制数的万位数不超过６，不用调整
                DJNZ    R2,HB20 ;处理完１６ｂｉｔ
                RET     
答 2: 谢谢。 答 3: 我需要的是十进制的数,BCD码显示部分不好处理。