EEPW论坛

问 感谢上次给的指点。

zlgARM 发表于 2005-2-28 13:09 Philips ARM ←返回版面    
re.
如果要中断嵌套，需要在中断服务程序中设置CPSR来打开中断。中断服务程序在IRQ.s文件（如果您没有这个文件，请下载新的工程模板）中添加中断句柄。

IRQ中的文件是：：：：：：：：：
CODE32

    AREA    IRQ,CODE,READONLY

    MACRO
$IRQ_Label HANDLER $IRQ_Exception_Function

        EXPORT  $IRQ_Label                      ; 输出的标号
        IMPORT  $IRQ_Exception_Function         ; 引用的外部标号

$IRQ_Label
        SUB     LR, LR, #4                      ; 计算返回地址
        STMFD   SP!, {R0-R3, R12, LR}           ; 保存任务环境
        MRS     R3, SPSR                        ; 保存状态
        STMFD   SP, {R3, SP, LR}^               ; 保存用户状态的R3,SP,LR,注意不能回写
                                                ; 如果回写的是用户的SP，所以后面要调整SP
        LDR     R2,  =OSIntNesting              ; OSIntNesting++
        LDRB    R1, [R2]
        ADD     R1, R1, #1
        STRB    R1, [R2]

        SUB     SP, SP, #4*3
        
        MSR     CPSR_c, #(NoInt | SYS32Mode)    ; 切换到系统模式
        CMP     R1, #1
        LDREQ   SP, =StackUsr
        
        BL      $IRQ_Exception_Function         ; 调用c语言的中断处理程序

        MSR     CPSR_c, #(NoInt | SYS32Mode)    ; 切换到系统模式
        LDR     R2, =OsEnterSum                 ; OsEnterSum,使OSIntExit退出时中断关闭
        MOV     R1, #1
        STR     R1, [R2]

        BL      OSIntExit

        LDR     R2, =OsEnterSum                 ; 因为中断服务程序要退出，所以OsEnterSum=0
        MOV     R1, #0
        STR     R1, [R2]

        MSR     CPSR_c, #(NoInt | IRQ32Mode)    ; 切换回irq模式
        LDMFD   SP, {R3, SP, LR}^               ; 恢复用户状态的R3,SP,LR,注意不能回写
                                                ; 如果回写的是用户的SP，所以后面要调整SP
        LDR     R0, =OSTCBHighRdy
        LDR     R0, [R0]
        LDR     R1, =OSTCBCur
        LDR     R1, [R1]
        CMP     R0, R1

        ADD     SP, SP, #4*3                    ;
        MSR     SPSR_cxsf, R3
        LDMEQFD SP!, {R0-R3, R12, PC}^          ; 不进行任务切换
        LDR     PC, =OSIntCtxSw                 ; 进行任务切换
    MEND

    END

我要中断嵌套是不是在+++调用c语言的中断处理程序+++前，设置CPSR_c开中断？那么不就是在BL之前设置MSR  CPSR_c, SYS32Mode

谢谢 答 1: re.不要去修改宏，设置CPSR打开中断的工作放在中断服务函数中进行，因为不是每个中断都要被嵌套的。而且移植代码的每一条指令都是有原因的，随意修改可能导致意料之外的问题。

最后建议您提问最好跟在原贴的后面，因为这里不是只有一个工程师支持，重新开贴，别的工程师就不清楚您原来问的什么了。 答 2: 明白了，谢谢您                答 3: 再来一个问题关于中断句柄，我发现在模板中，对于非向量中断和快中断都经过句柄的处理再调用c语言中断处理程序，而对于向量中断则不需要经过这个宏的处理，直接在c语言前加_irq就可以了。因为我试图设置向量中断经过宏就老是出错，跳不出中断处理程序。

请问我的理解对么？？
谢谢！！！